# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="1"
NEED_KDE="4.2"
OPENGL_REQUIRED="optional"
inherit kde4svn

# Install to KDEDIR rather than /usr, to slot properly.
PREFIX="${KDEDIR}"

DESCRIPTION="Advanced audio player based on KDE framework."
HOMEPAGE="http://amarok.kde.org/"

LICENSE="GPL-2"
KEYWORDS=""
SLOT="4.2"
IUSE="cdaudio daap debug ifp ipod mp3tunes mp4 mtp mysql njb +semantic-desktop"
ESVN_REPO_URI="svn://anonsvn.kde.org/home/kde/trunk/extragear/multimedia/amarok"

# daap are automagic

DEPEND="
	>=app-misc/strigi-0.5.7
	dev-db/sqlite:3
	>=media-libs/taglib-1.5
	|| ( x11-libs/qt-phonon:4 media-sound/phonon )
	kde-base/kdelibs:${SLOT}
	kde-base/libplasma:${SLOT}
	x11-libs/qt-webkit:4
	cdaudio? ( kde-base/libkcompactdisc:${SLOT}
		   kde-base/libkcddb:${SLOT} )
	ifp? ( media-libs/libifp )
	ipod? ( >=media-libs/libgpod-0.4.2 )
	mp3tunes? ( dev-libs/libxml2
		dev-libs/openssl
		net-libs/loudmouth
		net-misc/curl )
	mp4? ( media-libs/libmp4v2 )
	mtp? ( >=media-libs/libmtp-0.3.0 )
	mysql? ( >=virtual/mysql-4.1 )
	njb? ( >=media-libs/libnjb-2.2.4 )
	semantic-desktop? ( dev-libs/soprano )
	"
RDEPEND="${DEPEND}
	app-arch/unzip
	daap? ( www-servers/mongrel )
	"

pkg_setup() {
	if use semantic-desktop && ! built_with_use dev-libs/soprano sesame2 ; then
		eerror "dev-libs/soprano needs to be built with the sesame2 USE flag enabled"
		die
	fi
}

src_compile() {
	if use debug; then
		mycmakeargs="${mycmakeargs} -DCMAKE_BUILD_TYPE=debugfull"
	fi

	if ! use mp3tunes; then
		sed -e'/mp3tunes/ s:^:#DONOTWANT :' \
		-i "${S}"/src/browsers/servicebrowser/CMakeLists.txt \
		|| die "Deactivating mp3tunes failed."
	fi

	mycmakeargs="${mycmakeargs}
		-DCMAKE_INSTALL_PREFIX=${PREFIX}
		-DUSE_SYSTEM_SQLITE=ON
		$(cmake-utils_use_with cdaudio KdeMultimedia)
		$(cmake-utils_use_with ipod Ipod)
		$(cmake-utils_use_with ifp Ifp)
		$(cmake-utils_use_with mp4 Mp4v2)
		$(cmake-utils_use_with mtp Mtp)
		$(cmake-utils_use_with mysql MySQL)
		$(cmake-utils_use_with njb Njb)
		$(cmake-utils_use_with semantic-desktop Nepomuk)
		$(cmake-utils_use_with semantic-desktop Soprano)
	"
	kde4overlay-base_src_compile
}